Type::Tiny::Duck(3) User Contributed Perl Documentation Type::Tiny::Duck(3)

# [NAME](#NAME)

Type::Tiny::Duck - type constraints based on the "can" method

# [SYNOPSIS](#SYNOPSIS)

Using via Types::Standard:

```
  package Logger {
    use Moo;
    use Types::Standard qw( HasMethods Bool );
    
    has debugging => ( is => 'rw', isa => Bool, default => 0 );
    has output    => ( is => 'ro', isa => HasMethods[ 'print' ] );
    
    sub warn {
      my ( $self, $message ) = @_;
      $self->output->print( "[WARNING] $message\n" );
    }
    
    sub debug {
      my ( $self, $message ) = @_;
      $self->output->print( "[DEBUG] $message\n" ) if $self->debugging;
    }
  }
```

Using Type::Tiny::Duck's export feature:

```
  package Logger {
    use Moo;
    use Types::Standard qw( Bool );
    use Type::Tiny::Duck Printable => [ 'print' ];
    
    has debugging => ( is => 'rw', isa => Bool, default => 0 );
    has output    => ( is => 'ro', isa => Printable );
    
    sub warn {
      my ( $self, $message ) = @_;
      $self->output->print( "[WARNING] $message\n" );
    }
    
    sub debug {
      my ( $self, $message ) = @_;
      $self->output->print( "[DEBUG] $message\n" ) if $self->debugging;
    }
  }
```

Using Type::Tiny::Duck's object-oriented interface:

```
  package Logger {
    use Moo;
    use Types::Standard qw( Bool );
    use Type::Tiny::Duck;
    
    my $Printable = Type::Type::Duck->new(
      name    => 'Printable',
      methods => [ 'print' ],
    );
    
    has debugging => ( is => 'rw', isa => Bool, default => 0 );
    has output    => ( is => 'ro', isa => $Printable );
    
    sub warn {
      my ( $self, $message ) = @_;
      $self->output->print( "[WARNING] $message\n" );
    }
    
    sub debug {
      my ( $self, $message ) = @_;
      $self->output->print( "[DEBUG] $message\n" ) if $self->debugging;
    }
  }
```

# [STATUS](#STATUS)

This module is covered by the Type-Tiny stability policy.

# [DESCRIPTION](#DESCRIPTION)

Type constraints of the general form "{ $\_->can("method") }".

The name refers to the saying, "If it looks like a duck, swims like a duck, and quacks like a duck, then it probably is a duck". Duck typing can be a more flexible way of testing objects than relying on "isa", as it allows people to easily substitute mock objects.

This package inherits from Type::Tiny; see that for most documentation. Major differences are listed below:

## [Constructors](#Constructors)

The "new" constructor from Type::Tiny still works, of course. But there is also:

"new\_intersection( type\_constraints => \\@ducklings, %opts )"

Creates a new duck type constraint which is the intersection of existing duck type constraints. This allows the intersection of "HasMethods\['read']" and "HasMethods\['write']" to be simply "HasMethods\['read', 'write']" instead of a complex union type constraint with two duck type constraints as its children.

## [Attributes](#Attributes)

"methods"

An arrayref of method names.

"constraint"

Unlike Type::Tiny, you *cannot* pass a constraint coderef to the constructor. Instead rely on the default.

"inlined"

Unlike Type::Tiny, you *cannot* pass an inlining coderef to the constructor. Instead rely on the default.

"parent"

Parent is always **Types::Standard::Object**, and cannot be passed to the constructor.

## [Methods](#Methods)

[stringifies\_to($constraint)](#stringifies_to%28$constraint%29)

See Type::Tiny::ConstrainedObject.

[numifies\_to($constraint)](#numifies_to%28$constraint%29)

See Type::Tiny::ConstrainedObject.

"with\_attribute\_values($attr1 => $constraint1, ...)"

See Type::Tiny::ConstrainedObject.

## [Exports](#Exports)

Type::Tiny::Duck can be used as an exporter.

```
  use Type::Tiny::Duck HttpClient => [ 'get', 'post' ];
```

This will export the following functions into your namespace:

"HttpClient"

[is\_HttpClient( $value )](#is_HttpClient%28)

[assert\_HttpClient( $value )](#assert_HttpClient%28)

[to\_HttpClient( $value )](#to_HttpClient%28)

Multiple types can be exported at once:

```
  use Type::Tiny::Duck (
    HttpClient   => [ 'get', 'post' ],
    FtpClient    => [ 'upload', 'download' ],
  );
```

# [BUGS](#BUGS)

Please report any bugs to <https://github.com/tobyink/p5-type-tiny/issues>.

# [SEE ALSO](#SEE_ALSO)

Type::Tiny::Manual.

Type::Tiny.

Moose::Meta::TypeConstraint::DuckType.

# [AUTHOR](#AUTHOR)

Toby Inkster <tobyink@cpan.org>.

# [COPYRIGHT AND LICENCE](#COPYRIGHT_AND_LICENCE)

This software is copyright (c) 2013-2014, 2017-2025 by Toby Inkster.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

# [DISCLAIMER OF WARRANTIES](#DISCLAIMER_OF_WARRANTIES)

THIS PACKAGE IS PROVIDED "AS IS" AND WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF MERCHANTIBILITY AND FITNESS FOR A PARTICULAR PURPOSE.

2026-06-28 perl v5.42.2

---

Document: Type::Tiny::Duck(3pm) from perl-type-tiny 2.010001-r3 (Chainguard OS)
Source: https://github.com/tobyink/p5-type-tiny